var
  // Определение динамического массива
  byteArray  : Array of Byte;           // Одномерный массив
  multiArray : Array of Array of string;  // Многомерный массив

  i,j : Integer;

begin
  // Установка длины одномерного массива
  SetLength(byteArray, 5);

  // Показ размера и диапазона этого массива
  ShowMessage('Длина byteArray = '+IntToStr(Length(byteArray)));
  ShowMessage('Самый маленький элемент byteArray = '+IntToStr(Low(byteArray)));
  ShowMessage('Самый большой элемент byteArray = '+IntToStr(High(byteArray)));

  // Заполнение этого массива - помните, что динамические массивы начинаются с 0
  for i := 0 to 4 do
    byteArray[i] := i * 5;

  // Показ выбранных элементов массива
  ShowMessage('byteArray элемент 2 = '+IntToStr(byteArray[2]));
  ShowMessage('byteArray элемент 4 = '+IntToStr(byteArray[4]));

  // Установка длины 1-ого измерения многомерного массива
  SetLength(multiArray, 3);

  // Установка различной длины этих 3 подмассивов
  SetLength(multiArray[0], 1);
  SetLength(multiArray[1], 2);
  SetLength(multiArray[2], 3);

  // Установка и показ всех элементов этого массива
  for i := 0 to High(multiArray) do
    for j := 0 to High(multiArray[i]) do
    begin
      multiArray[i,j] := IntToStr(i+j);
      ShowMessage('multiArray['+intToStr(i)+','+intToStr(j)+'] = '+
                  multiArray[i,j]);
    end;
end;

// **********************

var
  // Определение динамического массива
  charArray : TCharArray;
  openArray : Array [0..2] of char;

  i : Integer;

begin
  // Передача неопределенного массива как динамический массив подпрограмме
  FurnishDynamicArray(charArray);

  // Заполнение массива для следующей подпрограммы
  openArray[0] := 'N';
  openArray[1] := 'o';
  openArray[2] := 'w';

  // Передача этого предопределенного массива как открытый массив подпрограмме
  ShowOpenTypeArray(openArray);

  // Показ всех элементов переданного массива
  for i := 0 to High(charArray) do
      ShowMessage('charArray['+intToStr(i)+'] = '+charArray[i]);

  // Передача подпрограмме числа символов как открытый постоянный массив
  ShowOpenConstArray(['H','e','l','l','o']);
end;

// Процедура, которая модифицирует динамический размер массива
// ВАЖНО - обратите внимание, что тип массива здесь не должен быть определен -
//         мы должны использовать тип массива, чтобы избежать массива,
//         обрабатываемого как открытый массив.
procedure TForm1.FurnishDynamicArray(var typeArray : TCharArray);
var
  i : Integer;

begin
  // Установка длины одномерного массива
  SetLength(typeArray, 5);

  // Заполнение этого массива - помните, что динамические массивы начинаются с 0
  for i := 0 to 4 do
    typeArray[i] := Chr(Ord('A') + i);
end;

// Процедура, которая принимает открытый массив
procedure TForm1.ShowOpenTypeArray(typeArray : Array of char);
var
  i : Integer;

begin
  // Показ всех элементов переданного массива
  for i := 0 to High(typeArray) do
    ShowMessage('typeArray['+intToStr(i)+'] = '+typeArray[i]);
end;

// Процедура, которая принимает открытый постоянный массив
procedure TForm1.ShowOpenConstArray(const constArray : Array of const);
var
  i : Integer;

begin
  // Показ всех элементов переданного массива
  for i := 0 to High(constArray) do
    ShowMessage('constArray['+intToStr(i)+'] = '+constArray[i].VChar);
end;